Welcome To The Home Of The Visual FoxPro Experts  
home. signup. forum. archives. search. google. articles. downloads. faq. members. weblogs. file info. rss.
 From: Stefan Wuebbe
  Where is Stefan Wuebbe?
 Hamburg
 Germany
 Stefan Wuebbe
 To: Ellick Yeung
  Where is Ellick Yeung?
 
 Hong Kong
 Ellick Yeung
 Tags
Subject: RE: Text box fore color in a grid
Thread ID: 189072 Message ID: 189103 # Views: 1 # Ratings: 1
Version: Visual FoxPro 9 SP2 Category: Grids
Date: Wednesday, August 13, 2008 12:17:42 PM         
   


> Your example will set the ForeColor for the ONE column "Column1", but what I am trying to do is just change the fore color of a single cell within the grid. Here is the example:
>
> Data shown in the grid as 3 columns and 3 rows.
>
> Col_a Col_b Col_c
> 100 200 500
> 150 70 500
> 20 300 600
>
> I want the value which is less than 100 show in RED, in this case Row 3 in Column A (value = 20) and Row 2 in Column B (value = 70).
>

So that it would look like this?:
LOCAL oForm as Form
oForm = CREATEOBJECT('TestForm')
oForm.Show(1)
RETURN

DEFINE CLASS TestForm as Form
	AutoCenter = .T.
	PROCEDURE Load
		CREATE CURSOR temp (Col_a Int, Col_b Int, Col_c Int)
		INSERT INTO temp VALUES (100, 200, 500)
		INSERT INTO temp VALUES (150, 70, 500)
		INSERT INTO temp VALUES (20, 300, 600)
		GO TOP
	ENDPROC

	ADD OBJECT Grid1 as Grid WITH ;
		RecordSource = 'temp', ColumnCount = 3
	PROCEDURE Grid1.Init()
		LOCAL loColumn, lcField
		FOR EACH loColumn IN This.Columns
			lcField = JUSTEXT(m.loColumn.ControlSource)
			loColumn.DynamicForeColor = 'Iif(' + m.lcField + '<100,RGB(255,0,0),RGB(0,0,0))'
		NEXT
	ENDPROC
ENDDEFINE



hth
-Stefan

ENTIRE THREAD

Text box fore color in a grid Posted by Ellick Yeung @ 8/13/2008 9:52:10 AM
RE: Text box fore color in a grid Posted by Stefan Wuebbe @ 8/13/2008 10:08:26 AM
RE: Text box fore color in a grid Posted by Ellick Yeung @ 8/13/2008 10:55:26 AM
RE: Text box fore color in a grid Posted by surinder singh @ 8/13/2008 11:04:56 AM
RE: Text box fore color in a grid Posted by Stefan Wuebbe @ 8/13/2008 12:17:42 PM
RE: Text box fore color in a grid Posted by Jun Tangunan @ 8/13/2008 1:13:57 PM
RE: Text box fore color in a grid Posted by Ellick Yeung @ 8/14/2008 4:56:36 AM
RE: Text box fore color in a grid Posted by surinder singh @ 8/13/2008 10:09:56 AM
RE: Text box fore color in a grid Posted by Mustapha Bihmouten @ 8/13/2008 10:11:24 AM
RE: Text box fore color in a grid Posted by Jun Tangunan @ 8/13/2008 10:14:53 AM